Bedrock CLI/API: how to associate an Action Group to an Agent Version

Okay I got it... Looks like there is a bug in the Terraform Agent resource attribute prepare_agent=true. The preparation does not happen.

I solved it by forcing the preparation with a Terraform null_resource and running aws cli commands. It is mandatory to wait for the Agent to be PREPARED before creating the Alias to then have the Action Group associated to it.

I leave this part of Terraform configuration below for reference.. Note that I commended the prepare_agent=true:

## AGENT >> components coordinator ====================================
resource "aws_bedrockagent_agent" "pm_monitor_agent" {
  agent_name              = "pm_monitor_agent"
  agent_resource_role_arn = aws_iam_role.pm_monitor_agent_role.arn
  description             = file("${path.module}/agent-description.txt")
  foundation_model        = data.aws_bedrock_foundation_model.pm_monitor_llm.id
  instruction             = file("${path.module}/agent-instructions.txt")
#   prepare_agent           = true
}

//@fix: the "prepare_agent=true" in the agent resource above does not work
// as expected, so here you force the agent preparation and then you wait
// for it for about 1 minute before creating an agent alias from the agent
// draft prepared.
resource "null_resource" "prepare_agent" {
  depends_on = [aws_bedrockagent_agent.pm_monitor_agent]
  provisioner "local-exec" {
    command = <<EOF
      aws bedrock-agent prepare-agent \
          --region ${var.aws_region} \
          --agent-id ${aws_bedrockagent_agent.pm_monitor_agent.agent_id}
    EOF
    }
}

// MUST adjust this values according to the instructions
// and time needed by the agent to come in "PREPARED" status.
// A better way would be use the Agent events to notify a
// lambda and create the Agent Alias from the lambda
resource "time_sleep" "waiting_agent_to_be_prepared" {
  depends_on = [null_resource.prepare_agent]
  create_duration = local.waiting_agent_to_be_prepared_time_delay
}

resource "aws_bedrockagent_agent_alias" "pm_monitor_agent_alias" {
  agent_alias_name = "pm_monitor_agent_alias"
  agent_id         = aws_bedrockagent_agent.pm_monitor_agent.agent_id
  depends_on = [
    time_sleep.waiting_agent_to_be_prepared
  ]
}